// selfhost/cmd/6l/main.ww — port of cmd/6l/main.c.
//
// 6l = amd64 static linker. Reads relocatable ELF .o files and
// SysV `ar` archives, resolves symbols, applies relocations, writes
// a static ELF executable.
//
//   6l_ww -o out file1.o file2.o libwwrt.a ...

use os;
use mem;
use sym;
use obj;
use pass;
use out;

def BASE: u64 = 4194304u64;	// 0x400000
def CODE_VA_OFF: u64 = 4096u64;	// .text starts at base + 0x1000

// Linker context lives in main's frame; arena gets passed in.
fn make_lnk(a: *arena) *lnk = {
	let l: *lnk = amalloc(a, 96u64): *lnk;
	l.a = a;
	return l;
};

fn streq_cs(a: *u8, lit: str) bool = {
	let n: u64 = lit.len: u64;
	let i: u64 = 0u64;
	for (i < n) {
		let li: i32 = i: i32;
		if (a[i] != lit[li]) { return false; };
		i += 1u64;
	};
	if (a[i] != 0u8) { return false; };
	return true;
};

export fn main(argc: i32, argv: **u8) i32 = {

	let out_path: *u8 = nil;
	// Inputs: store as **u8 (heap'd from a fixed-size buffer).
	let max_inputs: i32 = 64;
	let inputs: **u8 = os.alloc((max_inputs: u64) * 8u64): **u8;
	let ninputs: i32 = 0;

	let i: i32 = 1;
	for (i < argc) {
		let a: *u8 = argv[i];
		if (streq_cs(a, "-o")) {
			i += 1;
			if (i >= argc) {
				os.write(2, "6l: -o requires argument\n".ptr, 25u64);
				return 2;
			};
			out_path = argv[i];
		} else { if (a[0u64] == 45u8) {
			os.write(2, "6l: unknown flag\n".ptr, 17u64);
			return 2;
		} else {
			if (ninputs >= max_inputs) {
				os.write(2, "6l: too many inputs\n".ptr, 20u64);
				return 2;
			};
			inputs[ninputs] = a;
			ninputs += 1;
		}; };
		i += 1;
	};

	if (out_path == nil) {
		os.write(2, "usage: 6l_ww -o exe file1.o [file2.o...]\n".ptr, 41u64);
		return 2;
	};
	if (ninputs == 0) {
		os.write(2, "6l: no inputs\n".ptr, 14u64);
		return 2;
	};

	let a: *arena = newarena();
	let l: *lnk = make_lnk(a);

	// Seed _start so a libwwrt-style start.o is recognised as wanted.
	l_intern(l, "_start");

	let k: i32 = 0;
	for (k < ninputs) {
		if (l_load(l, inputs[k]) != 0) {
			return 1;
		};
		k += 1;
	};

	if (l_resolve(l) != 0) { return 1; };
	if (l_relocate(l, BASE + CODE_VA_OFF) != 0) { return 1; };

	let entry_sym: *lsym = l_lookup(l, "_start");
	if (entry_sym == nil) { entry_sym = l_lookup(l, "main"); }
	else { if (entry_sym.defined == 0) { entry_sym = l_lookup(l, "main"); }; };
	if (entry_sym == nil) {
		os.write(2, "6l: no _start or main symbol\n".ptr, 29u64);
		return 1;
	};
	if (entry_sym.defined == 0) {
		os.write(2, "6l: no _start or main symbol\n".ptr, 29u64);
		return 1;
	};

	// Open output: O_WRONLY|O_CREAT|O_TRUNC, mode 0755.
	let flags: i32 = os.O_WRONLY | os.O_CREAT | os.O_TRUNC;
	let fd: i32 = os.open(out_path, flags, 493i32);	// 0o755
	if (fd < 0) {
		os.write(2, "6l: cannot open output\n".ptr, 23u64);
		return 1;
	};

	let entry_va: u64 = BASE + CODE_VA_OFF + entry_sym.val;
	let rc: i32 = l_emit_elf(l, fd, BASE, entry_va);
	os.close(fd);
	return rc;
};